Tag: REXX

Using ISPF edit macros to displaying the junk in a catalog

You can use IDCAMS DCOLLECT to collect SMS information about data sets on your z/OS system. This gives lots of information about a dataset, size, creation date, SMS attributes etc.

With processing you can get reports on dataset, volumes, and what is using all the space. This allows you to delete dataset which are no longer needed.

This does not help when you are trying to clean out your catalogs, and removing stuff which should not be in that catalog. For example there are usually entries in a catalog which should really be in user catalogs.

I could not find tools to help me with this. I fell back to using and ISPF edit macro to process a LISTCAT listing and extracting relevant data. It is not difficult (once you know) and it is quick and easy.

This blog post gives some examples of how you can use ISPF edit macros to process data in data sets or spool.

The output from the short Rexx exec is

TCPIP.ETC.SERVICES             1998.284 B3SYS1
SYS1.RACFDS                    1999.288 B3CFG1
SYS1.IPLPARM                   1999.288 B3SYS1
...
LOG.MISC                       2025.107 USER04 
IBMUSER.S0W1.SPFTEMP3.CNTL     2026.002 USER07
IBMUSER.S0W1.SPFLOG1.LIST      2026.013 USER04
IBMUSER.SMF                    2026.013 USER07

With this I asked What is LOG.MISC 2025.107 doing in the catalog? It is there because I did not have the controls in place to stop people putting datasets into the catalog.

Instead of just displaying the information, I could have had the exec create IDCAMS statements, for example to get it recataloged, or deleted; based on creating date or other information.

Get your LISTCAT listing

I used

//IBMLISC JOB 1,MSGCLASS=H 
// EXPORT SYMLIST=(*) 
// SET CAT=&SYSVER. 
//S1  EXEC PGM=IDCAMS 
//SYSPRINT DD SYSOUT=* 
//SYSIN DD *,SYMBOLS=JCLONLY 
 LISTCAT NONVSAM CATALOG(CATALOG.&CAT..MASTER) ALL 
/*
  • The // SET CAT=&SYSVER. gets a local copy of the system symbol &SYSVER. You can use the operator command D SYMBOLS to list all the system symbols defined. On my system &SYSVER is Z31B
  • In //SYSIN DD *,SYMBOLS=JCLONLY the SYMBOLS=JCLONLY says substitute variables in the following SYSIN data, and substitute from the JCL symbols. &CAT is Z31B, and so the catalog name becomes CATALOG.Z31B.MASTER. You cannot use &SYMVER directly in the SYSIN data.

Edit the listing

I used SDSF and the SE line command on the output of the LISTCAT. You get an ISPF edit session with the spool data.

Run the exec

I have a Rexx exec called LISTCATN in USER.Z31B.CLIST. I’ll describe it in sections below

Standard Rexx starting code

/* REXX */ 
/* 
exec to Nonvsam records from a catalog listing 
*/ 
ADDRESS ISPEXEC 
'ISREDIT MACRO (parms) '

Use MACRO(parms) to get the parameters passed to the macro

Define parsing arguments

I define search arguments in a variable stem. This separates the data from the logic, and makes it easy to change or extend.

  data.1 = "NONVSAM 2 10" 
  fcol.1 = 18 
  flen.1 = 48 

  data.2 = "CREATION 38 48 " 
  fcol.2 = 54 
  flen.2 = 8 

  data.3 = "VOLSER 8 15  " 
  fcol.3 = 27 
  flen.3 = 8 

  data.0 = 3 
  sortcols  = "50 60"

Later there is code

  • do I = 1 to data.0 this processes each section in the stems
  • There a find data.1 which substitutes to “find NONVSAM 2 10”. This says Find the string NONVSAM in columns 2 to 10
  • If the find locates the string, the code retrieves the line. The code does a substring from fcol.1 for length flen.1 and saves the value
  • data.0 = 3 says there are three data sections.
  • sortcols = “50 60” is used at the end sort the file by the date column.

Remove uninteresting records

  "ISREDIT autosave off     " 
  "ISREDIT exclude all" 
  "ISREDIT find NONVSAM   2 10 ALL       " 
  "ISREDIT find CREATION ALL         " 
  "ISREDIT find VOLSER   ALL         " 
   if rc != 0 then data.0 = 2 /* ignore the volser */ 
  "ISREDIT delete all  x             "
  • “ISREDIT autosave off ” I have this as standard in ISPF edit macros, basically it says do not save the data if I press PF3.
  • “ISREDIT exclude all” –
  • “ISREDIT find NONVSAM 2 10 ALL ” find these lines
  • “ISREDIT find CREATION ALL ”
  • “ISREDIT find VOLSER ALL ”
  • If volser was not found, then listcat wasn’t specified with the right statement, so do not try to process any VOLSER records
    • if rc != 0 then data.0 = 2 /* ignore the volser */
  • “ISREDIT delete all x ” delete all the records which are still excluded leaving only the records I searched for.

Process the records

do j = 1  by 1 
  string = "" 
  do i = 1 to data.0 
    "ISREDIT find "data.i 
    if rc <> 0 then leave 
    "ISREDIT  (f) = LINENUM .ZCSR " 
    "ISREDIT  (d)  = LINE   " f 
     name = substr(d,fcol.i,flen.i) /* from col and length */ 
     string = string || " " || name 
  end 

  if rc <> 0 then leave 
  out.j = string 
end

This code uses the data in the variable stems defined higher up. It keeps the logic separate from the search data.

  • do j = 1 by 1 iterate through the whole file until the end of file
  • string = “” preset the output string
  • do i = 1 to data.0 for the records we specified
  • “ISREDIT find “data.i find it
  • if rc <> 0 then leave if not found then leave
  • “ISREDIT (f) = LINENUM .ZCSR ” Get the line number where the find found the data.
  • “ISREDIT ( d ) = LINE ” f get the line contents – getting the line number found in the previous step
  • name = substr(d,fcol.i,flen.i) /* from col and length */ extract the field of interest from the line
  • string = string || ” ” || name build up a string of the values found
  • end
  • if rc <> 0 then leave we got a not found, so end of file,
  • out.j = string save the data in a stem for processing below
  • end

Do something with the records

You can do processing on the data, for example create JCL to delete the dataset.

In this example I delete all records from the file, and insert the saved records

  "ISREDIT exclude all" 
  "ISREDIT delete all  x             " 
  do  i = 1 to j -1 
   v = out.i 
    "ISREDIT  LINE_after .zcsr  =   (v)" 
  end 
 "ISREDIT sort     " sortcols 
exit
  • “ISREDIT delete all “ delete all processed the lines in the file
  • do i = 1 to j -1 we have a stem of the records we processed iterate over them
  • v = out.i make a copy of the data, make it easy for ISPF. ISPF only does simple substitutions
  • “ISREDIT LINE_after .zcsr = (v)” insert after the current (last) line the value from v, which is the saved string.
  • end
  • “ISREDIT sort ” sortcols sort on the creation date
  • exit

The output

The output from this is the dataset name, the create date, and the volume it is on. 

TCPIP.ETC.SERVICES             1998.284 B3SYS1
SYS1.RACFDS                    1999.288 B3CFG1
SYS1.IPLPARM                   1999.288 B3SYS1
...
IBMUSER.S0W1.SPFTEMP3.CNTL     2026.002 USER07
IBMUSER.S0W1.SPFLOG1.LIST      2026.013 USER04
IBMUSER.SMF                    2026.013 USER07

From the data information I can see which entries were due to me – because they were all after the Jan 2025.

Different ways of processing records

Not every dataset has the same information. For example, deleting uninteresting rows

NONVSAM ------- ADCD.DYNISPF.ISPPLIB 
       DATASET-OWNER-----(NULL)     CREATION--------2016.236 
       VOLSER------------B3SYS1     DEVTYPE------X'3010200F' FSEQN------------------0 
NONVSAM ------- ADCD.WLM 
       DATASET-OWNER-----(NULL)     CREATION--------2023.010 
       STORAGECLASS -----SCBASE     MANAGEMENTCLASS---(NULL) 
       DATACLASS --------(NULL)     LBACKUP ---0000.000.0000 
       VOLSER------------B3USR1     DEVTYPE------X'3010200F' FSEQN------------------0

The second dataset ADCD.WLM has SMS information, Storage Class, Management Class, and Data Class, which are not present with the first dataset ADCD.DYNISPF.ISPPLIB.

You could process this sequentially and have logic like…

If the row starts with

  • NONVSAM – then write out the previous information, get the dataset name, and start again
  • VOLSER – then parse the volser value
  • DATASET – then parse the creation date
  • STORAGECLASS – then parse the SC and MC values
  • DATACLASS – then parse the DC value

For example 

"ISREDIT     (last)  = LINENUM .ZLAST" 
do j = 1  by 1  to last 
  "ISREDIT      ( d )  = LINE   " j 
  if substr(d,2,7) = "NONVSAM" then 
  do 
      count = count + 1 
      string =  dsn cd vol sc mc dc 
      sc = "        " 
      mc = "        " 
      dc = "        " 
      vol= "      " 
      dsn= "      " 
      cd = "      " 
      out.count = string 
      say string 
      /* do the next */ 
      dsn = substr(d,18,48) 
  end 
  else 
  if substr(d,9,7) = "DATASET" then cd = substr(d,54,8) 
  else 
  if substr(d,9,6) = "VOLSER" then vol = substr(d,27,6) 
  else 
  if substr(d,9,6) = "STORAG" then 
  do 
     sc = substr(d,27,8) 
     mc = substr(d,56,8) 
  end 
  else 
  if substr(d,9,6) = "DATACL" then vol = substr(d,27,8) 
end

This gives output like

NFS.CNTL                       2000.336 B3SYS1 
SYS1.RACFDS.BACKUP             2001.164 B3CFG1 
SYS1.UADS                      2003.137 B3CFG1 
NETVIEW.ADCD.NTVTABS           2009.027 B3USR1 SCBASE   (NULL) 
SYT1.ZOS.CNTL                  2012.013 B3USR1 SCBASE   (NULL) 
TCPIP.PROFILE.TCPIP            2016.236 B3SYS1

So not difficult at all.

Using Rexx under z/OS Unix Services to display thread information

I wanted to display information about threads running in a big Java application, and see what was executing during set up.

Rexx can provide information on threads, and so I was able to create a script which provided process thread data. There was documentation, but it was not very clear, so I’m documenting what I learned

My program

/* rexx */ 
do k = 1 to 20 
  call procinfo 
  say "jobname  asid    ppid    pid    threadid  tcb    cmdline" 
  do i=1 to bpxw_pid.0 
    x =procinfo(bpxw_pid.i,'process') 
    if x = '' then iterate 
    if bpxw_LOGNAME.i <> "ZWESVUSR" then iterate 
    y = procinfo(bpxw_pid.i,'thread') 
    if y = '' then iterate 
    do j=1 to bpxw_threads 
      xtcb = d2x( bpxw_TCB.j) 
      say bpxw_JOBNAME  d2x(bpxw_ASID)  right(bpxw_PPID,8), 
          right(bpxw_PID,8)  bpxw_THREAD_ID.j xtcb  bpxw_CMDLINE 
    end 
  end 
  sleep(1) 
end
  • call procinfo returns a list of process ids in a stem bpxw_pid. and userids in a stem bpxw_LOGNAME
  • do i=1 to bpxw_pid.0 iterate through the list of the processes
  • x =procinfo(bpxw_pid.i,’process’) get the process information about the process id in bpxw_pid.i.
  • if x = ” then iterate if the thread no longer exists – do the next one
  • if bpxw_LOGNAME.i <> “ZWESVUSR” then iterate ignore threads from other userids
  • y = procinfo(bpxw_pid.i,’thread’) get the thread information for the process id in bpxw_pid.i.
  • if y = ” then iterate if no data is returned skip this
  • do j=1 to bpxw_threads for each thread in the process …
  • xtcb = d2x( bpxw_TCB.j) convert the thread TCB from decimal to hex.
  • say …
    • bpxw_JOBNAME this is from the process information
    • d2x(bpxw_ASID) display the ASID of the process in hex
    • bpxw_THREAD_ID.j the thread id.

Can I easily make an ISPF edit line command macro?

The key word in the title is easily. If you search for “Working with an edit line command table”, the documentation gives you instructions on how to create a table, then add your definition, create your macro, and then use it. When you were expecting to do this invisibly for the end user, it is a lot of work.

A command line rexx program can process line commands. I created a command line program so when I use it, and use S or SS..SS line commands, the macro can extract the tagged lines, and so do things with the tagged data.

The command line Rexx

/* REXX */ 
address isredit 
'MACRO (a) NOPROCESS ' 
'process range S             ' 
IF RC = 0 
THEN DO 
  "(first) = LINENUM .ZFRANGE" 
  "(last) = LINENUM .ZLRANGE" 
  data = "" 
  /* build up a long string from the tagged lines */
  do i = first to last 
    "(l) = LINE (i)" 
    data = data || strip(l) || " " 
  end 
  l = data 
  address ispexec "edit dataset('COLIN.$$TEMP$$') macro(l2) parm(l)" 
END

Where the lines of interest are

  • ‘MACRO (a) NOPROCESS ‘
    • Usually when a command line macro is processed, ISPF processes any outstanding line commands (such as D) before processing any commands in the rexx exec. The NOPROCESS says – hold off doing this until instructed.
    • a is the data passed in
  • ‘process range S ‘
    • This locates any line commands beginning with S, for a single line, or SS…SS for multiple lins.
  • if rc = 0 then do
  • “(first) = LINENUM .ZFRANGE”
    • get the line number of the First in the RANGE
  • “(last) = LINENUM .ZLRANGE”
    • get the line number of the Last in the Range.
  • data = “”
  • do i = first to last /* process the data build up the string */
    • “(l) = LINE (i)”
    • data = data || strip(l) || ” “
  • end
  • ldata = data
  • address ispexec “edit dataset(‘COLIN.$$TEMP$$’) macro(l2) parm(ldata)”
    • Invoke edit on a file – invoke macro l2, and pass the data in the rexx variable ldata
  • END

If the “process range” gives a non zero return code, set an error message

else do 
  zedsmsg = 'You need to specify line prefix s|ss ss' 
  zedlmsg = 'You need to specify line prefix s|ss ss long message' 
  address ispexec  'SETMSG MSG(ISRZ001)' 
end

This sets a Short message (zedSmsg) which is display at the top right of the display, and a long message (zedLmsg) if the user presses PF1 on the short message.

Macro L2

This macro is processed when the edit dataset(..) macro(l2) command is issued

/* REXX */ 
address isredit 
'MACRO (a)              ' 

say "Passed data" a
...