Processing lines in ASCII files in ISPF edit macros

I was trying to make it easier to read the trace lines from Liberty. These lines can be hundreds of characters long – and it needs many scrolls right and left to display it.
If I extracted and displayed the line – it displayed garbage because the line was in ASCII, and if you just displayed the line, it displays the ASCII values.

This raised several challenges.

1. How do do you convert from ASCII to EBCDIC in an ISPF Rexx macro.
2. How do you nicely display a long line on one screen.

How do do you convert from ASCII to EBCDIC in an ISPF Rexx macro?

I could not find any easy code to copy, so I had to write code to create the ASCII to EBCDIC mapping in Rexx.

/* REXX */ 
/* 
exec to display long (Liberty) logs by flowing text 
*/ 
ADDRESS ISPEXEC 
'ISREDIT MACRO' 
 "ISREDIT autosave off     " 
 ascii0  = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F" 
 ebcdic0 = "................................" 
 ascii1= "202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F40" 
 ebcdic1 = " !..$.&'()*+,-./0123456789:;<=>?@" 
 ascii2 ="4142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F60" 
 ebcdic2=  "ABCDEFGHIJKLMNOPQRSTUVWXYZ(\)._." 
 ascii3 ="6162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F" 
 ebcdic3= "abcdefghijklmnopqrstuvwxyz{|}~." 
                                                                                
 ascii   = ascii0 || ascii1 || ascii2||ascii3 
 ebcdic = ebcdic0 || ebcdic1|| ebcdic2||ebcdic3 
                                                                                
 ascii = x2c(ascii) 
 /*get the current line number, and extract it  */ 
   "ISREDIT         (l) = LINENUM .ZCSR " 
   "ISREDIT      ( d )  = LINE   " l 
/* convert it to ebcdic  */ 
out = translate(d,ebcdic,ascii) 

The upper part of the code just creates the translation tables. For example ASCII 0x21i is EBCDIC “!”.

The code

"ISREDIT         (l) = LINENUM .ZCSR " 
   "ISREDIT      ( d )  = LINE   " l 
/* convert it to ebcdic from ascii  */ 
out = translate(d,ebcdic,ascii) 
say out

reads the current (.ZCSR) line of the file into variable d, converts to EBCDIC and displays it.

How do you nicely display a long line on one screen?

I used

out = translate(d,ebcdic,ascii) 
/* and display it */ 
out = strip(out) 
do  i = 1 to length(out) by 72 
    say substr(out,i,72 ) 
end 

which cuts the message into 72 byte chunks.

I enhanced this to allow me to enter a number of lines on the macro

/* REXX */ 
/* 
exec to display long (Liberty) logs by flowing text 
*/ 
ADDRESS ISPEXEC 
'ISREDIT MACRO (lines) ' 
 "ISREDIT autosave off     " 
 "ISREDIT (fcol,lcol)  = DISPLAY_COLS" /* get width of the screen */
 width = lcol - fcol 
 ascii0  = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F" 
 ebcdic0 = "................................" 
 ascii1= "202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F40" 
 ebcdic1 = " !..$.&'()*+,-./0123456789:;<=>?@" 
 ascii2 ="4142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F60" 
 ebcdic2=  "ABCDEFGHIJKLMNOPQRSTUVWXYZ(\)._." 
 ascii3 ="6162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F" 
 ebcdic3= "abcdefghijklmnopqrstuvwxyz{|}~." 
                                                                              
 ascii   = ascii0 || ascii1 || ascii2||ascii3 
 ebcdic = ebcdic0 || ebcdic1|| ebcdic2||ebcdic3 
                                                                              
 ascii = x2c(ascii) 
 /*get the current line number, and extract it  */ 
   "ISREDIT         (last) =  LINENUM .ZLAST" 
   "ISREDIT         (l)    = LINENUM .ZCSR " 
 if lines = "" then 
    lines = 1 
 do j = l to (l + lines  - 1) 
    if (j > last) then leave 
   "ISREDIT      ( d )  = LINE   " j 
   if rc <> 0 then leave 
    /* convert it to ebcdic  */ 
    out = translate(d,ebcdic,ascii) 
    /* and display it */ 
    out = strip(out) 
    /* display full width, based on screen size */

    do  i = 1 to length(out) by width 
        say substr(out,i,width) 
    end 
    say " " 
 end 
exit 

so if my macro is called zz, I can issue the command zz 3 and it displays 3 lines in the file

The couple of hours it took me to write this have made my life so much easier.